MacWorld 2000 February/Macworld (2000-02).dmg/Cool Extras!/WallBall Screen Saver/intro.dxr/00010_Loop Until Next Frame is Available.ls

Text File | 1999-11-11 | 3.3 KB | 63 lines

property WhichFrame, loopMarker, loopFrame, waitAction

on getPropertyDescriptionList
  markList = []
  markListPopDown = ["{Next Marker}"]
  nextList = ["{Next Marker}"]
  prevList = []
  numMarkers = the number of lines in the labelList
  repeat with i = 1 to numMarkers
    L = (the labelList).line[i]
    add(markList, L)
    add(markListPopDown, L)
  end repeat
  repeat with e = 1 to markListPopDown.count
    if getAt(markListPopDown, e) = EMPTY then
      markListPopDown.deleteAt(e)
    end if
  end repeat
  totalMarkers = markListPopDown.count
  if markListPopDown[totalMarkers] = EMPTY then
    markListPopDown.deleteAt(totalMarkers)
  end if
  repeat with r = 1 to markListPopDown.count
    if the frame > getAt(markListPopDown, r).marker then
      add(prevList, getAt(markListPopDown, r))
    end if
  end repeat
  deleteAt(prevList, 1)
  if prevList <> [] then
    description = [#waitAction: [#comment: "Loop Type:", #format: #symbol, #range: [#LoopOnCurrentFrame, #LoopToSpecifiedFrame, #LoopToSpecifiedMarker], #default: #LoopOnCurrentFrame], #loopFrame: [#comment: "Loop to Frame:", #format: #integer, #default: 1], #loopMarker: [#comment: "Loop to Marker:", #format: #string, #range: prevList, #default: getLast(prevList)]]
    return description
  else
    description = [#waitAction: [#comment: "Loop Type:", #format: #symbol, #range: [#LoopOnCurrentFrame, #LoopToSpecifiedFrame], #default: #LoopOnCurrentFrame], #loopFrame: [#comment: "Loop to Frame:", #format: #integer, #default: 1]]
    return description
  end if
end

on exitFrame me
  if not frameReady(the frame + 1) then
    the idleLoadMode = 2
    preLoad(the frame + 1)
    the idleLoadMode = 0
    case waitAction of
      #LoopOnCurrentFrame:
        go(the frame)
      #LoopToSpecifiedFrame:
        go(loopFrame)
      #LoopToSpecifiedMarker:
        go(loopMarker)
    end case
  else
    nothing()
  end if
end

on getBehaviorDescription
  return "What this behavior does:" & RETURN & RETURN & "Instructs the playback head to wait for media used in the next frame.   Use this in movies that are authored to stream over the Internet, where media in the next frame may not be available yet.  When the media in the next frame becomes available, the playback head will continue to the next frame." & RETURN & RETURN & RETURN & "How to use:" & RETURN & RETURN & "1. Drag the behavior to the script channel of the score in the frame that should serve as the end of the looping sequence." & RETURN & RETURN & "2. Select a 'Loop Type.'" & RETURN & RETURN & "Options include 'LoopOnCurrentFrame' (the default) and 'LoopToSpecifiedFrame.'  Additionally, if one or more markers exist prior to the frame the behavior is in, 'LoopToSpecifiedMarker' becomes a third looping option." & RETURN & RETURN & "3. Assign a destination to loop to while waiting for streaming media." & RETURN & RETURN & "This is only required when selecting a 'Loop Type' that requires a particular frame or marker to loop to." & RETURN & RETURN & "Note:  This behavior should be used for Shockwave only."
end

on getBehaviorTooltip
  return "Use this to loop the playback head" & RETURN & "until media in the subsequent frame" & RETURN & "is available for use." & RETURN & RETURN & "To use, drop behavior on the script" & RETURN & "channel of the score in the frame" & RETURN & "that will serve as the end of the" & RETURN & "looping sequence."
end